Assembler

Pirroh · 31. Mai 2005, 11:53

Ich will doch mal wissen, wer hier alles schon mal Assembler geschrieben hat. Wer nur die höheren Programmiersprachen gewohnt ist, der wird Assembler hassen und sich davor zurückhalten. (Ich muss mich schin dazu zwingen ;)). Vielleicht habt ihr auch ein paar beispielprogramme? Ich hänge mal meine Bin-Watch an.

Quellcode

.MODEL small
.STACK 100h
.DATA
Minute DB 0
Stunde DB 0
Sekunde DB 0
Hintergrundfarbe DB 01100000b
Hintergrundfarbe_2 DB 01110000b
schriftfarbe DB 00001111b
farbe_null DB 00110000b
farbe_eins DB 01010000b
balkenlaenge DB 00001101b
.CODE
mov ax,@data
mov ds,ax
;-----
call cls
mov ch,20h
mov cl,20h
mov ah,01h
int 10h
@schleife:
mov dl,1
mov dh,1
mov bh,0
mov ah, 02h
int 10h
mov bx,040h
mov es,bx
mov byte ptr cx,es:[6eh]
mov al, cl
mov stunde, cl
aam
mov si,712
mov cl, ah
mov ch, al
add cl, 30h
add ch, 30h
mov ax,0b800h
mov es,ax
mov dl, hintergrundfarbe
add dl, schriftfarbe
mov byte ptr es:[si],cl
mov byte ptr es:[si+1],dl
mov byte ptr es:[si+2],ch
mov byte ptr es:[si+3],dl
mov byte ptr es:[si+4],':'
mov byte ptr es:[si+5],dl
mov ax,40h
mov es,ax
mov ax,es:[6ch]
mov bx,1000
mul bx
mov bx,18200
div bx
mov dx,0
mov bl,60
div bl
mov minute, al
mov sekunde, ah
push ax
aam
mov cl, ah
mov ch, al
add cl, 30h
add ch, 30h
mov ax,0b800h
mov es,ax
mov dl, hintergrundfarbe
add dl, schriftfarbe
mov byte ptr es:[si+6],cl
mov byte ptr es:[si+7],dl
mov byte ptr es:[si+8],ch
mov byte ptr es:[si+9],dl
mov byte ptr es:[si+10],':'
mov byte ptr es:[si+11],dl
pop ax
mov al, ah
xor ah,ah
aam
mov cl, ah
mov ch, al
add cl, 30h
add ch, 30h
mov ax,0b800h
mov es,ax
mov byte ptr es:[si+12],cl
mov byte ptr es:[si+13],dl
mov byte ptr es:[si+14],ch
mov byte ptr es:[si+15],dl
;beginn Binäruhr
mov ax, 0b800h ;gilt die ganze zeit
mov es, ax
;;;Beginn Stunde;;;
mov si, 1176 ;Speicheradressen vorbereiten (für die Stunden)
mov bl, stunde
mov cx, 5
@stunde:
sub si, 6
shr bl, 1
jc stunde_eins
jmp Stunden_weiter
stunde_eins:
mov dl, 1
call balken_zeichnen
jmp stunden_ende
Stunden_Weiter:
mov dl, 0
call balken_zeichnen
stunden_ende:
loop @stunde
;;;Beginn Minute;;;
add si, 74 ;Speicheradressen vorbereiten (für die Minuten)
mov bl, Minute
mov cx, 6
@minute:
sub si, 6
shr bl, 1
jc minute_eins
jmp minute_weiter
minute_eins:
mov dl, 1
call balken_zeichnen
jmp minute_ende
minute_Weiter:
mov dl, 0
call balken_zeichnen
minute_ende:
loop @minute
;;;Beginn Sekunde;;;
add si, 78 ;Speicheradressen vorbereiten (für die Sekunden)
mov bl, Sekunde
mov cx, 6
@sekunde:
sub si, 6
shr bl, 1
jc Sekunde_eins
jmp Sekunde_weiter
sekunde_eins:
mov dl, 1
call balken_zeichnen
jmp sekunde_ende
Sekunde_Weiter:
mov dl, 0
call balken_zeichnen
sekunde_ende:
loop @sekunde
mov ah,01h
int 16h
jnz @ende
jmp @schleife
@ende:
;-----
mov ah,4ch
int 21h
;===========
; Beginn der Unterprogramme
;===========
; dl "1" oder "0"
;
Balken_Zeichnen proc near
push cx
push si
push bx
mov bl, farbe_eins
mov bh, farbe_null
shr dl, 1
jc Balken_1
jmp Balken_weiter
Balken_1:
mov ch, 0
mov cl, balkenlaenge
Sprung_1:
mov byte ptr es:[si], " "
mov byte ptr es:[si+1], bl
add si, 160
loop Sprung_1
jmp ende_balken
Balken_weiter:
mov ch, 0
mov cl, balkenlaenge
Sprung_2:
mov byte ptr es:[si], " "
mov byte ptr es:[si+1], bh
add si, 160
loop Sprung_2
ende_balken:
pop bx
pop si
pop cx
ret
endp Balken_Zeichnen
cls proc near
push ax
push si
push dx
mov dl, Hintergrundfarbe
mov ax, 0b800h
mov es, ax
mov si, 0
noch_eins:
mov byte ptr es:[si], " "
cmp si, 2080
jge andere_farbe
mov dl, Hintergrundfarbe
mov byte ptr es:[si+1], dl
jmp weiter_farbe
andere_farbe:
mov dl, Hintergrundfarbe_2
mov byte ptr es:[si+1], dl
weiter_farbe:
add si, 2
cmp si, 4002
jnz Noch_eins
ende_cls:
pop dx
pop si
pop ax
ret
cls endp
END

Alles anzeigen

MoD3000 · 31. Mai 2005, 12:14

Und was sagt uns das? gcc -S regelt ausserdem.
Wo bleibt eigentlich die ausreichende Wuerdigung fuer SPARC-Assembler. Haltet eine _grosse_ Tuete bereit.

Goliat Skipson · 31. Mai 2005, 12:43

naja ... meiner meinung nach hat assembler in der 'alltags programmierung' so ziemlich ausgesorgt ...
natürlich könnte man diverse programme die in einer highlevel language geschrieben sind nocheinmal überarbeiten ... aber bei der komplexität heutiger programme, und der leistung der compiler ist das eigentlich nichtmehr möglich und nötig ...
assembler hat wohl noch seinen sinn ... so werden viele industriemaschinen noch direkt mit assembler abarten programmiert ... aber im 'wahren leben' braucht man assembler wohl nimmer ...

MoD3000 · 31. Mai 2005, 13:27

Du wirst dich wundern, aber jedes gute Programm wird "nachoptimiert". Ob immer per Hand ist ne andere Frage.
Und die tausend verschiedenen DSPs dieser Welt sind ein verschwindendes Problem?

JaWaS · 31. Mai 2005, 14:20

Wuahah die Sprache gefällt mir ned, ich mags eher entweder like Java, C++ bzw C (auch wenn ich nur Java richtig beherrsche) oder halt PHP bzw MySQL obwohl die anweißungen in PHP eh ähnlich aufgebaut sind.

Three of Five · 31. Mai 2005, 16:02

jawas, naja, asm is eh in jeder architektur anders

das hier is ja x86 asm, genauer lernen wir asm des 8086
ich find es eigendlich recht gut, sehr gut für das verständniss der grundlagen
und man freut sich immer ziemlich wenn dann ein prog funktioniert
vllt sollten wir hier auch mal die fire.exe posten, ca 200zeilen asm code aber was da rauskommt is schon ziemlich nett
vllt sollte robin hier auch mal seinen in delphi geschriebenen asmide posten *g*

LuxY · 31. Mai 2005, 19:36

Ich komm auch besser mit C/Perl/PHP zurecht als mit asm muss ich sagen

Cypher · 31. Mai 2005, 21:38

also ich fühl mich mit c ganz gut bedient, was low level programmierung angeht (sofern man es nötig hat)

ansonsten gibts ja auch noch c++, perl, ....
und andere sprachen lernen sich ja auch relativ flott. assembler muss ich glaub ich nächstes jahr in der schule lernen um irgendwelche platinen zu programmieren... naja, is bestimmt ganz nützlich wenn man das kann *an deassemblieren denk* (schreibt man das so :think:

)

MoD3000 · 31. Mai 2005, 23:08

Du musst zu viel Zeit haben. Am besten gleich explorer.exe deassemblieren. Den Source (moeglichst C) kannst du ja dann hier veroeffentlichen.

SirBelial · 1. Juni 2005, 06:54

Aber man kanns auch übertreiben.

Pirroh · 1. Juni 2005, 10:44

Original von Three of Five
[...]
vllt sollten wir hier auch mal die fire.exe posten, ca 200zeilen asm code aber was da rauskommt is schon ziemlich nett
[...]

Ok, gesagt getan. Damit keine Missverständnisse aufkommen: ich habe sie nicht geschrieben und komm auch bei dem Quelltext nich hinterher (da muss ich wohl noch lange üben *seufz*)

die Kommentare ( ; ) sind übrigens auch ganz lustig

Brainfuck-Quellcode

.MODEL SMALL
.STACK 100h
.DATA
Seed DW 3749h
Meldung DB 'E-Mail: BlueCobold@gmx.de',10,13,'HomePage: http://BlueCobold.18yo.de$'
Screen DB 65000 DUP (?)
.386
.CODE
;--------------- GRAFIK-MODUS -------------------
InitGraph PROC
mov ax, 13h ; kürzer!
int 10h
push 0a000h ; das ist auch cool...
pop es
ret
InitGraph ENDP
;--------------- RANDOM -------------------------
Random PROC
MOV AX, Seed ; Move the seed value into AX
MOV DX, 8407H ; Move 8405H into DX
MUL DX ; Put 8405H x Seed into DX:AX
INC AX ; Increment AX
MOV Seed, AX ; We have a new seed
RET
Random ENDP
;--------------- VIRTUELLEN SCREEN LÖSCHEN ----------------
ClearPage PROC
mov di, Offset Screen
push es
push ds
pop es
mov cx, 16250
xor eax, eax
rep stosd
pop es
ret
ClearPage ENDP
;--------------- PALETTE ------------------------
SetUpPalette PROC ;geht das nicht kürzer?
mov si, Offset Screen ;geht bestimmt!
mov cx, 64
@pal:
xor ax, ax
mov al, 64
sub al, cl
mov [si], al
mov [si+1], ah
mov [si+2], ah
mov [si+193], al
mov [si+194], ah
mov [si+386], al
mov ah, 63
mov al, ah
mov [si+192], ah
mov [si+384], ax
mov [si+576], ax
mov [si+578], ah
add si, 3
dec cx
jnz @pal
mov si, Offset Screen
xor ax, ax
mov dx, 3c8h
out dx, al
inc dx
mov cx, 768
rep outsb
ret
SetUpPalette ENDP
;------------- WAITRETRACE --------------------
WaitRetrace PROC
mov dx, 3dah
@Bildaufbau:
in al, dx
test al, 8
jnz @Bildaufbau
@Retrace:
in al, dx
test al, 8
jz @Retrace
ret
WaitRetrace ENDP
;------------ FUELLEN -------------------------
Fuellen PROC
mov si, 64003
mov cx, 80
@FuellenLoop:
call Random
and dx, 7
jz @PixelSetzen
dec dx
jz @PixelSetzen
dec dx
jnz @NichtNull
@PixelSetzen:
mov al, 255
mov ah, al
mov dx, ax
shl eax,16
mov ax, dx
mov [si+1], ax ; mit 32 Bit arbeiten!
mov [si-3], eax
mov [si-323], eax
mov [si-319], ax
mov [si+317], eax
mov [si+321], ax
@NichtNull:
add si, 4
dec cx
jnz @FuellenLoop
ret
Fuellen ENDP
;--------------- VIRTUELLE PAGE KOPIEREN -----------------
ShowPage PROC
mov cx, 16000
mov si, OFFSET Screen
xor di, di
rep movsd
ret
ShowPage ENDP
;--------------- Feuer - EFFEKT -----------------------
DoFire PROC
mov si, Offset Screen+640
mov cx, 64640
@Blur:
xor bx, bx
xor ax, ax
mov bl, [si-1]
add ax, bx
mov bl, [si+1]
add ax, bx
mov bl, [si-320]
add ax, bx
mov bl, [si+320]
add ax, bx
mov bl, [si-319]
add ax, bx
mov bl, [si+319]
add ax, bx
mov bl, [si-321]
add ax, bx
mov bl, [si+321]
add ax, bx
shr ax, 3
jz @skip
dec ax
jz @skip
dec ax
@skip:
mov ds:[si-640], al
inc si
dec cx
jnz @Blur
ret
DoFire ENDP
;--------------- HAUPTPROGRAMM -----------------------
Start:
push @data
pop ds
call InitGraph
call ClearPage
call SetUpPalette
;------------ BLUR ------------------------
cli
BlurLoop:
call Fuellen
call DoFire
call WaitRetrace
call ShowPage
in al, 60h ;das mach ich kürzer
cmp al, 1
jnz BlurLoop
sti
;------------------------------------------
mov ax, 3h
int 10h
mov dx, Offset Meldung
mov ah, 9
int 21h
mov ah, 4Ch
int 21h
END Start

Alles anzeigen

Quellcode

Brainfuck-Quellcode

Teilen